How Many Ways To Create Macro Variables In Sas

This tutorial explains SAS macros with practical examples. SAS Macro programming is considered as an advanced SAS. Knowing SAS Macros is an advantage in the job market over other candidates. Upon completion of this tutorial, you would understand how to create macros and where they can be used. It's generally said smart programming reduce workload and helps to win over your boss.

SAS Macro for Beginners

What are Macros

Macros are used to automate the repetitive task. It can make your work faster by automating the task that requires writing same lines of code every day. It can also be used when you design a complex algorithm and want to make usage of code user friendly so that people who are not comfortable with programming can use your algorithm.

Introduction to SAS Macro Programming

A macro variable is used to store a value. The value is always character. The character value can include variable-name, letters, numbers or any text you want substituted in your program.

Macro Variables are of two types -

Local - If the macro variable is defined inside a macro code, then scope is local. It would be available for use in that macro only and gets removed when the macro is finished.
Global - If the macro variable is defined outside a macro code, then scope is global. It can be use any where in the SAS program and gets removed at the end of the session.

5 ways to create macro variables -

The following is a list of various ways to create a macro variable with examples.

1. %LET

It can defined inside or outside a macro.

The syntax of the %LET statement -

%LET macro-variable-name = value;
%LET x = 5;

Example - To store system date

%let dt = &sysdate;

How to use Macro Variables

Macro variables are referenced by using ampersand (&) followed by macro variable name.

& <Macro variable Name>

To view in log window what macro variable would return, use %PUT statement :

%put &dt.;
%put NOTE : system data is &dt.;

Result : NOTE : system data is 23DEC16

Notice that unlike the PUT statement the text string is not enclosed in quotes. The quotes are not needed because, unlike in the DATA step, the macro facility does not need to distinguish between variable names and text strings.

2. Macro Parameters

Example : Suppose you are asked to write a macro that returns mean value of a variable. The analysis variable, input and output data sets are dynamic.

%macro test (input =, ivar=, output=);
proc means data = &input noprint;
var &ivar;
output out = &output mean= ;
run;
%mend;

In the above code, test is a macro, input, ivar and output are local macro variables.

How to call a macro -

%test(input=sashelp.heart, ivar= height, output=test);

In this case, we are giving flexibility to users to provide information of input dataset name, the analysis variable and output dataset and the macro returns the mean value of the analysis variable in the output dataset.

3. INTO clause in PROC SQL

Example : Calculate average height and store in a macro variable

proc means data = sashelp.heart noprint;
var height;
output out = test mean= avg_height;
run;

proc sql noprint;
select avg_height into :var1
from test;
quit;
%put &var1;

Result : 64.81318

4. CALL SYMPUT routine

The syntax of CALL SYMPUT :

CALL SYMPUT(macro_varname,value);

data _null_;
set test;
call symput ('var2',avg_height);
run;
%put &var2;

5. ITERATIVE %DO

The syntax of iterative %DO -

%DO macro-variable = start %TO stop <%BY increment>;
. . . text . . .
%END;

Example -

%macro calcl(start,stop);
%do year = &start %to &stop;
data test;
set yr&year;
year = 2000 + &year;
run;
%end;
%mend calcl;

How to use conditional processing %IF %THEN ?

In SAS Macros, we can apply conditional statements using %IF %THEN like below -

options mindelimiter=,;
options minoperator;
%MACRO test();
%DO i = 1 %to 9 ;
%if &i in (1,3,5,7,9) %then %do;%PUT i = &i - odd;
%END;
%ELSE %DO;%PUT i = &i - even;
%end;
%end;%MEND;
%test();

If you are confused between IF-THEN and %IF-THEN and don't know when to use, check out the link below -
Tutorial : Difference between IF THEN and %IF %THEN

SAS Macro Functions

There are some SAS macro functions which help you to execute various operations within a macro. They are listed below -

1. %EVAL Function

It is used to perform mathematical and logical operation with macro variables.

Example -

%let x = 10;
%let y = 20;
%let z = &x * &y;
%put &z;

It returns "10*20".

%let z2 = %eval(&x*&y);
%put &z2;

Note :

%let last = %eval (4.5+3.2); returns error as it cannot perform arithmetic calculations with operands that have the floating point values. It is when the %SYSEVALF function comes into picture.

%let last2 = %sysevalf(4.5+3.2);
%put &last2;

2. %SYSFUNC Function

There are several useful Base SAS function that are not directly available in Macro, %Sysfunc enables those function to make them work in a macro.

%let dt3 = %sysfunc(date(),yymmdd10.);

It returns 2016-12-23.

3. %STR Function

Usage I : This function removes the normal meaning of following token + – * /, > < = ; " LT EQ GT LE GE LE NE AND OR NOT blank.

Suppose we need to store PROC PRINT; RUN; command in a macro variable.

%let exmp0 = proc print; run;;
%put &exmp0;

Result : proc print
Since the semicolon following PRINT terminates the %LET statement. It does not consider RUN statement. To workaround this issue, let's use %STR function.

%let exmpl = %str(proc print; run;) ;
%put &exmpl;

Result : proc print; run;

Usage II : Precede with % sign when you use single or double quotation in macro

%let var=%str(a%");

%put &var;

Result : a"

If you would not use %STR function in the above example, you would not be able to store quotes in a macro variable.

Usage III : It also preserves leading and trailing blanks of the string.

%let dt= %str( a );
%put &dt;

Run the above code and compare it with the code below, you would understand the difference -

%let dt= a ;
%put &dt;

4. %NRSTR Function

%NRSTR works similar to %STR works except it does not resolve the % and & but stop the macro triggers.

%let exmpl = %nrstr(proc print; run;) ;
%put &exmpl;

Result :proc print; run;

%put "Difference between %NRSTR(&SYSDATE9) and &SYSDATE9";

Result : "Difference between &SYSDATE9 and 23DEC2016"

In the above case, %NRSTR() stops the &SYSDATE9 macro function.

5. %SCAN Function

It returns the nth word in a string.

%let var = var1 var2 var3;
%let varName =%scan(&var,1,%str( ));
%put &varName;

Result : var1

Concatenation of Macro Variables

Suppose you have 3 macro variables and the third variable is actually a concatenation of the first 2 variables' value.

%let x = var;
%let y = 1 ;
%let var1 = 25;
%let z = &&&x&y;
%put &x &y &z;

Result : var 1 25

&z returns 25 because first && resolves to &, &x resolves to var, &y. resolves to 1. So var1 returns 25

Detailed Tutorial : Multiple Ampersand Macro Variables

How to store list of values in a macro variable

Suppose you have a list of names and you want to store them in a macro variable. It can be done by using SEPARATED BY ' ' keyword in PROC SQL.

data temp;
input name $16.;
cards;
Deepanshu Bhalla
Dave Jhonson
Ram Prasad
;
run;

proc sql;
select name into: myvar separated by ','
from temp;
quit;

%put &myvar; returns Deepanshu Bhalla,Dave Jhonson,Ram Prasad

In this case, we have used comma(,) as a delimiter. We can use any other delimiter.

How to debug SAS Macros

There are some system options that can be used to debug SAS Macros:

1. MPRINT

MPRINT translates the macro language to regular SAS language. It displays all the SAS statements of the resolved macro code.

options mprint;
%macro test (input =,output=);
proc means data = &input noprint;
var height;
output out = &output mean= ;
run;
%mend;
%test(input=sashelp.heart,output=test);

It returns the following message in LOG window :

MPRINT(TEST): proc means data = sashelp.heart noprint;
MPRINT(TEST): var height;
MPRINT(TEST): output out = test mean= ;
MPRINT(TEST): run;

2. MLOGIC

It is very helpful when we deal with nested macros (Macro inside another macro). Often we use %DO loops and or %IF-%THEN-%ELSE statements inside the macro code and LOGIC option will display how the macro variable resolved each time in the LOG file as TRUE or FALSE.

options mlogic;
options mindelimiter=,;
options minoperator;
%MACRO test();
%DO i = 1 %to 9 ;
%if &i in (1,3,5,7,9) %then %do;
%PUT i = &i - odd;
%END;
%ELSE %DO;
%PUT i = &i - even;
%end;
%end;
%MEND;
%test();

In the log window, see what MLOGIC option produces -

MLOGIC(TEST): %DO loop beginning; index variable I; start value is 1; stop value is 9; by value is 1.
MLOGIC(TEST): %IF condition &i in (1,3,5,7,9) is TRUE
MLOGIC(TEST): %PUT i = &i - odd
i = 1 - odd
MLOGIC(TEST): %DO loop index variable I is now 2; loop will iterate again.
MLOGIC(TEST): %IF condition &i in (1,3,5,7,9) is FALSE
MLOGIC(TEST): %PUT i = &i - even
i = 2 - even

3. SYMBOLGEN

It writes the results of resolving macro variable references to the SAS log for debugging.

options symbolgen;
%macro test (input =,output=);
proc means data = &input noprint;
var height;
output out = &output mean= ;
run;
%mend;
%test(input=sashelp.heart,output=test);

SYMBOLGEN: Macro variable INPUT resolves to sashelp.heart
SYMBOLGEN: Macro variable OUTPUT resolves to test

Difference between MPRINT and SYMBOLGEN

See the log generated by these two options. MPRINT optionprints all the statements within the macro (not just macro variables). Whereas, SYMBOLGEN option prints only the results of macro variables.

How to turn off macro debugging options

options nomprint nomlogic nosymbolgen;

All of these options can be turned off together as specified above. Or one of them can be turned off and remaining ones keep turned on.

Important Tips

1. Use double quotes to reference macro variables.

SAS Macros Tutorial

2. The quotes are not needed in %PUT.

%put NOTE : system data is &dt.;

3. Use Proc PRINTTO for saving log in an external text file.

proc printto log="C:\Users\Deepanshu\Downloads\LOG2.txt" new;
run;

4. Clear LOG and OUTPUT Window

DM "Log" clear continue;
DM "Output" clear continue;

How to call SAS Macro from External Location

1. % INCLUDE

%include "C:\Users\Deepanshu\Downloads\test.sas";
%test;

Suppose your macro is stored in a location and you need to call it from the location. You can accomplish this task using %Include.

2. Autocall Macro Facility and Stored Compiled Macro

Practice Question - Try it Yourself

Calculate distinct number of categories (levels) in variable make in dataset sashelp.cars andstore it in a macro variable and later multiply the macro variable by 2.5

Answer it in comment box below

About Author:

Deepanshu founded ListenData with a simple objective - Make analytics easy to understand and follow. He has over 10 years of experience in data science. During his tenure, he has worked with global clients in various domains like Banking, Insurance, Private Equity, Telecom and Human Resource.